Project: OPENARR.DPR

Project Structure

• OPENARR.DPR
• OPENARRF.PAS
• OPENARRF.DFM

program OpenArr;

uses
  Forms,
  OpenArrF in 'OpenArrF.pas' {Form1};

{$R *.RES}

begin
  Application.Initialize;
  Application.CreateForm(TForm1, Form1);
  Application.Run;
end.

unit OpenArrF;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    Button4: TButton;
    Button6: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
    procedure Button4Click(Sender: TObject);
    procedure Button6Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.DFM}

// typed open array
function Sum (const A: array of Integer): Integer;
var
  I: Integer;
begin
  Result := 0;
  for I := Low (A) to High (A) do
    Result := Result + A[I];
end;

// untyped open array
function SumAll (const Args: array of const): Extended;
var
  I: Integer;
begin
  Result := 0;
  for I := Low (Args) to High (Args) do
    case Args [I].VType of
      vtInteger: Result :=
        Result + Args [I].VInteger;
      vtBoolean:
        if Args [I].VBoolean then
          Result := Result + 1;
      vtChar:
        Result := Result + Ord (Args [I].VChar);
      vtExtended:
        Result := Result + Args [I].VExtended^;
      vtString:
        Result := Result + StrToIntDef ((Args [I].VString^), 0);
      vtAnsiString:
        Result := Result + StrToIntDef (
          string (Args [I].VAnsiString), 0);
      vtWideChar:
        Result := Result + Ord (Args [I].VWideChar);
      vtCurrency:
        Result := Result + Args [I].VCurrency^;
    end;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  X, Y, I: Integer;
begin
  Y := 10;
  I := 3;
  X := Sum ([10, Y, 27*I]);
  ShowMessage ('Sum ([10, Y, 27*I]) => ' +
    IntToStr (X));
end;

procedure TForm1.Button2Click(Sender: TObject);
var
  List: array [1..10] of Integer;
  X, I: Integer;
begin
  // initialize array
  for I := Low (List) to High (List) do
    List [I] := I * 2;
  // call
  X := Sum (List);
  ShowMessage ('Sum (List)) => ' +
    IntToStr (X));
end;

procedure TForm1.Button3Click(Sender: TObject);
var
  List: array [1..10] of Integer;
  X, I: Integer;
begin
  // initialize array
  for I := Low (List) to High (List) do
    List [I] := I * 2;
  // call
  X := Sum (Slice (List, 5));
  ShowMessage ('Sum (Slice (List, 5)) => ' +
    IntToStr (X));
end;

procedure TForm1.Button4Click(Sender: TObject);
var
  X: Extended;
  Y: Integer;
begin
  Y := 10;
  X := SumAll ([Y * Y, 'k', True, 10.34, '999']);
  ShowMessage (Format (
    'SumAll ([Y * Y, ''k'', True, 10.34, ''999'']) => %n',
    [X]));
end;

procedure TForm1.Button6Click(Sender: TObject);
var
  DynArr: array of Integer;
  I, X: Integer;
begin
  SetLength (DynArr, 10);
  for I := 0 to High (DynArr) do
    DynArr [I] := I * 3;
  X := Sum (DynArr);
  ShowMessage ('Sum (DynArr) => ' + IntToStr (X));
end;

end.

object Form1: TForm1
  Left = 246
  Top = 123
  Width = 228
  Height = 250
  Caption = 'Open Array'
  Color = clBtnFace
  Font.Charset = DEFAULT_CHARSET
  Font.Color = clWindowText
  Font.Height = -11
  Font.Name = 'MS Sans Serif'
  Font.Style = []
  OldCreateOrder = True
  PixelsPerInch = 96
  TextHeight = 13
  object Button1: TButton
    Left = 64
    Top = 24
    Width = 75
    Height = 25
    Caption = 'Plain Call'
    TabOrder = 0
    OnClick = Button1Click
  end
  object Button2: TButton
    Left = 64
    Top = 88
    Width = 75
    Height = 25
    Caption = 'Slice'
    TabOrder = 1
    OnClick = Button2Click
  end
  object Button3: TButton
    Left = 64
    Top = 120
    Width = 75
    Height = 25
    Caption = 'Partial Slice'
    TabOrder = 2
    OnClick = Button3Click
  end
  object Button4: TButton
    Left = 64
    Top = 168
    Width = 75
    Height = 25
    Caption = 'Untyped'
    TabOrder = 3
    OnClick = Button4Click
  end
  object Button6: TButton
    Left = 64
    Top = 56
    Width = 75
    Height = 25
    Caption = 'Dynamic'
    TabOrder = 4
    OnClick = Button6Click
  end
end